Notion Formler

Samling af Notion-formler til at holde styr på deadlines og afhængigheder mellem opgaver.

1. Dependency alert #

Advarer hvis en afhængighed starter efter denne opgaves startdato.

if(
  not empty(prop("Date")) and
  /* Check if any dependency starts after this task's start date */
  prop("Afhængig af").some(
    not empty(current.prop("Date")) and
    dateStart(current.prop("Date")) > dateStart(prop("Date"))
  ),
  "❗️ dependency alert",
  ""
)

2. Deadline / not started check #

Tjekker om deadline er overskredet uden at opgaven er markeret som færdig, eller om opgaven burde være i gang.

if(empty(prop("Date")), "",
  ifs(
    /* Past the end date and not yet done */
    prop("Status") != "Done" and dateEnd(prop("Date")) < today(), "⭕️ tjek deadline",
    /* Today falls within the date range but task hasn't been started */
    prop("Status") == "Not started" and dateStart(prop("Date")) <= today() and dateEnd(prop("Date")) >= today(), "⭕️ Not started?",
    ""
  )
)

3. Blocked by dependencies #

Viser om opgaven er blokeret af afhængigheder, og hvor mange af dem der mangler at blive færdige.

lets(
  /* Count how many dependencies are not yet done */
  notDoneCount, prop("Afhængig af")
    .filter(current.prop("Status") != "Done")
    .length(),
  totalDeps, prop("Afhængig af").length(),
  ifs(
    /* No blocking dependencies - task is free to proceed */
    notDoneCount == 0, "",
    /* All dependencies are blocking */
    notDoneCount == totalDeps, "⚠️ Blocked",
    /* Some dependencies are blocking - show fraction */
    "⚠️ Blocked (" + format(notDoneCount) + "/" + format(totalDeps) + ")"
  )
)